Contents

# Mathematical Functions

This category contains the Mathematical functions for Calc. To open the Function Wizard, choose Insert - Function.

## AGGREGATE

This function returns an aggregate result of the calculations in the range. You can use different aggregate functions listed below. The Aggregate function enables you to omit hidden rows, errors, SUBTOTAL and other AGGREGATE function results in the calculation.

## RAWSUBTRACT

Subtracts a set of numbers and gives the result without eliminating small roundoff errors.

## SUM

Adds a set of numbers.

## SUMIF

Determines which values in a range of cells meet a specified criterion, then returns the sum of the matching values. Alternatively the function can determine which values in one range of cells meet a criterion, then return the sum of values in the corresponding cells in a second range of cells.

## COLOR

Return a numeric value calculated by a combination of three colors (red, green and blue) and the alpha channel, in the RGBA color system. The result depends on the color system used by your computer.

## SUMIFS

Returns the sum of the values of cells in a range that meets multiple criteria in multiple ranges.

## ABS

Returns the absolute value of a number.

#### Syntax

ABS(Number)

Number is the number whose absolute value is to be calculated. The absolute value of a number is its value without the +/- sign.

#### Example

=ABS(-56) returns 56.

=ABS(12) returns 12.

=ABS(0) returns 0.

## ACOS

Returns the inverse trigonometric cosine of a number.

#### Syntax

ACOS(Number)

This function returns the inverse trigonometric cosine of Number, that is the angle (in radians) whose cosine is Number. The angle returned is between 0 and PI.

To return the angle in degrees, use the DEGREES function.

#### Example

=ACOS(-1) returns 3.14159265358979 (PI radians)

=DEGREES(ACOS(0.5)) returns 60. The cosine of 60 degrees is 0.5.

## ACOSH

Returns the inverse hyperbolic cosine of a number.

#### Syntax

ACOSH(Number)

This function returns the inverse hyperbolic cosine of Number, that is the number whose hyperbolic cosine is Number.

Number must be greater than or equal to 1.

#### Example

=ACOSH(1) returns 0.

=ACOSH(COSH(4)) returns 4.

## ACOT

Returns the inverse cotangent (the arccotangent) of the given number.

#### Syntax

ACOT(Number)

This function returns the inverse trigonometric cotangent of Number, that is the angle (in radians) whose cotangent is Number. The angle returned is between 0 and PI.

To return the angle in degrees, use the DEGREES function.

#### Example

=ACOT(1) returns 0.785398163397448 (PI/4 radians).

=DEGREES(ACOT(1)) returns 45. The tangent of 45 degrees is 1.

## ACOTH

Returns the inverse hyperbolic cotangent of the given number.

#### Syntax

ACOTH(Number)

This function returns the inverse hyperbolic cotangent of Number, that is the number whose hyperbolic cotangent is Number.

An error results if Number is between -1 and 1 inclusive.

#### Example

=ACOTH(1.1) returns inverse hyperbolic cotangent of 1.1, approximately 1.52226.

## ASIN

Returns the inverse trigonometric sine of a number.

#### Syntax

ASIN(Number)

This function returns the inverse trigonometric sine of Number, that is the angle (in radians) whose sine is Number. The angle returned is between -PI/2 and +PI/2.

To return the angle in degrees, use the DEGREES function.

#### Example

=ASIN(0) returns 0.

=ASIN(1) returns 1.5707963267949 (PI/2 radians).

=DEGREES(ASIN(0.5)) returns 30. The sine of 30 degrees is 0.5.

## ASINH

Returns the inverse hyperbolic sine of a number.

#### Syntax

ASINH(Number)

This function returns the inverse hyperbolic sine of Number, that is the number whose hyperbolic sine is Number.

#### Example

=ASINH(-90) returns approximately -5.1929877.

=ASINH(SINH(4)) returns 4.

## ATAN

Returns the inverse trigonometric tangent of a number.

#### Syntax

ATAN(Number)

This function returns the inverse trigonometric tangent of Number, that is the angle (in radians) whose tangent is Number. The angle returned is between -PI/2 and PI/2.

To return the angle in degrees, use the DEGREES function.

#### Example

=ATAN(1) returns 0.785398163397448 (PI/4 radians).

=DEGREES(ATAN(1)) returns 45. The tangent of 45 degrees is 1.

## ATAN2

Returns the angle (in radians) between the x-axis and a line from the origin to the point (NumberX|NumberY).

This function is part of the Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

#### Syntax

ATAN2(NumberX; NumberY)

NumberX is the value of the x coordinate.

NumberY is the value of the y coordinate.

Programming languages have usually the opposite order of arguments for their atan2() function.

ATAN2 returns the angle (in radians) between the x-axis and a line from the origin to the point (NumberX|NumberY)

#### Example

=ATAN2(-5;9) returns 2.07789 radians.

To get the angle in degrees apply the DEGREES function to the result.

=DEGREES(ATAN2(12.3;12.3)) returns 45. The tangent of 45 degrees is 1.

LibreOffice results 0 for ATAN2(0;0).

The function can be used in converting cartesian coordinates to polar coordinates.

=DEGREES(ATAN2(-8;5)) returns φ = 147.9 degrees

## ATANH

Returns the inverse hyperbolic tangent of a number.

#### Syntax

ATANH(Number)

This function returns the inverse hyperbolic tangent of Number, that is the number whose hyperbolic tangent is Number.

Number must obey the condition -1 < number < 1.

#### Example

=ATANH(0) returns 0.

## COMBIN

Returns the number of combinations for elements without repetition.

#### Syntax

COMBIN(Count1; Count2)

Count1 is the number of items in the set.

Count2 is the number of items to choose from the set.

COMBIN returns the number of ordered ways to choose these items. For example if there are 3 items A, B and C in a set, you can choose 2 items in 3 different ways, namely AB, AC and BC.

COMBIN implements the formula: Count1!/(Count2!*(Count1-Count2)!)

#### Example

=COMBIN(3;2) returns 3.

## COMBINA

Returns the number of combinations of a subset of items including repetitions.

#### Syntax

COMBINA(Count1; Count2)

Count1 is the number of items in the set.

Count2 is the number of items to choose from the set.

COMBINA returns the number of unique ways to choose these items, where the order of choosing is irrelevant, and repetition of items is allowed. For example if there are 3 items A, B and C in a set, you can choose 2 items in 6 different ways, namely AA, AB, AC, BB, BC and CC.

COMBINA implements the formula: (Count1+Count2-1)! / (Count2!(Count1-1)!)

#### Example

=COMBINA(3;2) returns 6.

## CONVERT_OOO

Converts to euros a currency value expressed in one of the legacy currencies of 19 member states of the Eurozone, and vice versa. The conversion uses the fixed exchange rates at which the legacy currencies entered the euro.

We recommend using the more flexible EUROCONVERT function for converting between these currencies. CONVERT_OOO is not a standardized function and is not portable.

#### Syntax

CONVERT_OOO(Value; "Text1"; "Text2")

Value is the amount of the currency to be converted.

Text1 is a three-character string that specifies the currency to be converted from.

Text2 is a three-character string that specifies the currency to be converted to.

Text1 and Text2 must each take one of the following values: "ATS", "BEF", "CYP", "DEM", "EEK", "ESP", "EUR", "FIM", "FRF", "GRD", "IEP", "ITL", "LTL", "LUF", "LVL", "MTL", "NLG", "PTE", "SIT", and "SKK".

One, and only one, of Text1 or Text2 must be equal to "EUR".

#### Example

=CONVERT_OOO(100;"ATS";"EUR") returns the euro value of 100 Austrian schillings.

=CONVERT_OOO(100;"EUR";"DEM") converts 100 euros into German marks.

Refer to the CONVERT_OOO wiki page for more details about this function.

## COS

Returns the cosine of the given angle (in radians).

#### Syntax

COS(Number)

Returns the (trigonometric) cosine of Number, the angle in radians.

To return the cosine of an angle in degrees, use the RADIANS function.

#### Example

=COS(PI()*2) returns 1, the cosine of 2*PI radians.

=COS(RADIANS(60)) returns 0.5, the cosine of 60 degrees.

## COSH

Returns the hyperbolic cosine of a number.

#### Syntax

COSH(Number)

Returns the hyperbolic cosine of Number.

#### Example

=COSH(0) returns 1, the hyperbolic cosine of 0.

## COT

Returns the cotangent of the given angle (in radians).

#### Syntax

COT(Number)

Returns the (trigonometric) cotangent of Number, the angle in radians.

To return the cotangent of an angle in degrees, use the RADIANS function.

The cotangent of an angle is equivalent to 1 divided by the tangent of that angle.

### Examples:

=COT(PI()/4) returns 1, the cotangent of PI/4 radians.

=COT(RADIANS(45)) returns 1, the cotangent of 45 degrees.

## COTH

Returns the hyperbolic cotangent of a given number (angle).

#### Syntax

COTH(Number)

Returns the hyperbolic cotangent of Number.

#### Example

=COTH(1) returns the hyperbolic cotangent of 1, approximately 1.3130.

## CSC

Returns the cosecant of the given angle (in radians). The cosecant of an angle is equivalent to 1 divided by the sine of that angle

This function is available since LibreOffice 3.5.

#### Syntax

CSC(Number)

Returns the (trigonometric) cosecant of Number, the angle in radians.

To return the cosecant of an angle in degrees, use the RADIANS function.

#### Example

=CSC(PI()/4) returns approximately 1.4142135624, the inverse of the sine of PI/4 radians.

=CSC(RADIANS(30)) returns 2, the cosecant of 30 degrees.

## CSCH

Returns the hyperbolic cosecant of a number.

This function is available since LibreOffice 3.5.

#### Syntax

CSCH(Number)

Returns the hyperbolic cosecant of Number.

#### Example

=CSCH(1) returns approximately 0.8509181282, the hyperbolic cosecant of 1.

## DEGREES

Converts radians into degrees.

#### Syntax

DEGREES(Number)

Number is the angle in radians to be converted to degrees.

#### Example

=DEGREES(PI()) returns 180 degrees.

## EUROCONVERT

Converts between old European national currency and to and from Euros.

#### Syntax

EUROCONVERT(Value; "From_currency"; "To_currency" [; full_precision [; triangulation_precision]])

Value is the amount of the currency to be converted.

From_currency and To_currency are the currency units to convert from and to respectively. These must be text, the official abbreviation for the currency (for example, "EUR"). The rates (shown per Euro) were set by the European Commission.

Full_precision is optional. If omitted or False, the result is rounded according to the decimals of the To currency. If Full_precision is True, the result is not rounded.

Triangulation_precision is optional. If Triangulation_precision is given and >=3, the intermediate result of a triangular conversion (currency1,EUR,currency2) is rounded to that precision. If Triangulation_precision is omitted, the intermediate result is not rounded. Also if To currency is "EUR", Triangulation_precision is used as if triangulation was needed and conversion from EUR to EUR was applied.

### Examples

=EUROCONVERT(100;"ATS";"EUR") converts 100 Austrian Schillings into Euros.

=EUROCONVERT(100;"EUR";"DEM") converts 100 Euros into German Marks.

## EVEN

Rounds a positive number up to the next even integer and a negative number down to the next even integer.

#### Syntax

EVEN(Number)

Returns Number rounded to the next even integer up, away from zero.

#### Example

=EVEN(2.3) returns 4.

=EVEN(2) returns 2.

=EVEN(0) returns 0.

=EVEN(-0.5) returns -2.

## EXP

Returns e raised to the power of a number. The constant e has a value of approximately 2.71828182845904.

#### Syntax

EXP(Number)

Number is the power to which e is to be raised.

#### Example

=EXP(1) returns 2.71828182845904, the mathematical constant e to Calc's accuracy.

## FACT

Returns the factorial of a non-negative integer.

#### Syntax

FACT(Integer)

Returns Integer!, the factorial of Integer, calculated as 1*2*3*4* ... * Integer.

Returns the "invalid argument" error if the argument is negative integer.

Returns the #VALUE! error if the argument is greater than 170, cause too large integer (approximately 7E+306.

=FACT(0) returns 1 by definition.

If the argument is a non-integer number, it is converted to its floor integer value.

#### Example

=FACT(3) returns 6.

=FACT(3.8) returns 6.

=FACT(0) returns 1.

## GCD

Returns the greatest common divisor of two or more integers.

The greatest common divisor is the positive largest integer which will divide, without remainder, each of the given integers.

#### Syntax

GCD(Integer 1 [; Integer 2 [; … [; Integer 255]]])

Integer 1; Integer 2; … ; Integer 255 are integers, references to cells or to cell ranges of integers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

=GCD(16;32;24) gives the result 8, because 8 is the largest number that can divide 16, 24 and 32 without a remainder.

=GCD(B1:B3) where cells B1, B2, B3 contain 9, 12, 9 gives 3.

## GCD_EXCEL2003

The result is the greatest common divisor of a list of numbers.

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

#### Syntax

GCD_EXCEL2003(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1; Number 2; … ; Number 255 are numbers, references to cells or to cell ranges of numbers.

#### Example

=GCD_EXCEL2003(5;15;25) returns 5.

## INT

Rounds a number down to the nearest integer.

#### Syntax

INT(Number)

Returns Number rounded down to the nearest integer.

Negative numbers round down to the integer below.

#### Example

=INT(5.7) returns 5.

=INT(-1.3) returns -2.

## LCM

Returns the least common multiple of one or more integers.

#### Syntax

LCM(Integer 1 [; Integer 2 [; … [; Integer 255]]])

Integer 1; Integer 2; … ; Integer 255 are integers, references to cells or to cell ranges of integers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

If you enter the numbers 512; 1024 and 2000 as Integer 1;2 and 3, then 128000 will be returned.

## LCM_EXCEL2003

The result is the lowest common multiple of a list of numbers.

The functions whose names end with _ADD or _EXCEL2003 return the same results as the corresponding Microsoft Excel 2003 functions without the suffix. Use the functions without suffix to get results based on international standards.

#### Syntax

LCM_EXCEL2003(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1; Number 2; … ; Number 255 are numbers, references to cells or to cell ranges of numbers.

#### Example

=LCM_EXCEL2003(5;15;25) returns 75.

## LN

Returns the natural logarithm based on the constant e of a number. The constant e has a value of approximately 2.71828182845904.

#### Syntax

LN(Number)

Number is the value whose natural logarithm is to be calculated.

#### Example

=LN(3) returns the natural logarithm of 3 (approximately 1.0986).

=LN(EXP(321)) returns 321.

## LOG

Returns the logarithm of a number to the specified base.

#### Syntax

LOG(Number [; Base])

Number is the value whose logarithm is to be calculated.

Base (optional) is the base for the logarithm calculation. If omitted, Base 10 is assumed.

#### Example

=LOG(10;3) returns the logarithm to base 3 of 10 (approximately 2.0959).

=LOG(7^4;7) returns 4.

## LOG10

Returns the base-10 logarithm of a number.

#### Syntax

LOG10(Number)

Returns the logarithm to base 10 of Number.

#### Example

=LOG10(5) returns the base-10 logarithm of 5 (approximately 0.69897).

## MOD

Returns the remainder when one integer is divided by another.

#### Syntax

MOD(Dividend; Divisor)

For integer arguments this function returns Dividend modulo Divisor, that is the remainder when Dividend is divided by Divisor.

This function is implemented as Dividend - Divisor * INT(Dividend/Divisor) , and this formula gives the result if the arguments are not integer.

#### Example

=MOD(22;3) returns 1, the remainder when 22 is divided by 3.

=MOD(11.25;2.5) returns 1.25.

## MROUND

Returns a number rounded to the nearest multiple of another number.

#### Syntax

MROUND(Number; Multiple)

Returns Number rounded to the nearest multiple of Multiple.

An alternative implementation would be Multiple * ROUND(Number/Multiple).

#### Example

=MROUND(15.5;3) returns 15, as 15.5 is closer to 15 (= 3*5) than to 18 (= 3*6).

=MROUND(1.4;0.5) returns 1.5 (= 0.5*3).

## MULTINOMIAL

Returns the factorial of the sum of the arguments divided by the product of the factorials of the arguments.

#### Syntax

MULTINOMIAL(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1; Number 2; … ; Number 255 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

=MULTINOMIAL(F11:H11) returns 1260, if F11 to H11 contain the values 2, 3 and 4. This corresponds to the formula =(2+3+4)! / (2!*3!*4!)

## ODD

Rounds a positive number up to the nearest odd integer and a negative number down to the nearest odd integer.

#### Syntax

ODD(Number)

Returns Number rounded to the next odd integer up, away from zero.

#### Example

=ODD(1.2) returns 3.

=ODD(1) returns 1.

=ODD(0) returns 1.

=ODD(-3.1) returns -5.

## PI

Returns 3.14159265358979, the value of the mathematical constant PI to 14 decimal places.

#### Syntax

PI()

#### Example

=PI() returns 3.14159265358979.

## POWER

Returns a number raised to another number.

#### Syntax

POWER(Base; Exponent)

Returns Base raised to the power of Exponent.

The same result may be achieved by using the exponentiation operator ^: Base^Exponent

=POWER(0,0) returns 1; =POWER(0,X) reports the #NUM! error when exponent X is negative.

=POWER(B,X) may or may not report a #NUM! error when B is negative and X is not an integer.

#### Example

=POWER(4;3) returns 64, which is 4 to the power of 3.

=4^3 also returns 4 to the power of 3.

=POWER(2;-3) returns 0.125.

=POWER(-2;1/3) returns -1.25992104989487.

=POWER(-2;2/3) returns the #NUM! error.

## PRODUCT

Multiplies all the numbers given as arguments and returns the product.

#### Syntax

PRODUCT(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1; Number 2; … ; Number 255 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

=PRODUCT(2;3;4) returns 24.

## QUOTIENT

Returns the integer part of a division operation.

#### Syntax

QUOTIENT(Numerator; Denominator)

Returns the integer part of Numerator divided by Denominator.

QUOTIENT is equivalent to INT(numerator/denominator) for same-sign numerator and denominator, except that it may report errors with different error codes. More generally, it is equivalent to INT(numerator/denominator/SIGN(numerator/denominator))*SIGN(numerator/denominator).

#### Example

=QUOTIENT(11;3) returns 3. The remainder of 2 is lost.

## RADIANS

Converts degrees to radians.

#### Syntax

RADIANS(Number)

Number is the angle in degrees to be converted to radians.

#### Example

=RADIANS(90) returns 1.5707963267949, which is PI/2 to Calc's accuracy.

## RAND

Returns a random number between 0 and 1.

This function is always recalculated whenever a recalculation occurs.

#### Syntax

RAND()

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

To generate random numbers which never recalculate, either:

- Copy cells each containing =RAND(), and use Edit - Paste Special (with Paste All and Formulas not marked and Numbers marked).

- Use the Fill Cell command with random numbers (Sheet - Fill Cells - Fill Random Numbers).

- Use the RAND.NV() function for non-volatile random numbers.

#### Example

=RAND() returns a random number between 0 and 1.

## RANDBETWEEN

Returns an integer random number in a specified range.

This function is always recalculated whenever a recalculation occurs.

#### Syntax

RANDBETWEEN(Bottom; Top)

Returns an integer random number between integers Bottom and Top (both inclusive).

This function produces a new random number each time Calc recalculates. To force Calc to recalculate manually press F9.

To generate random numbers which never recalculate, copy cells containing this function, and use Edit - Paste Special (with Paste All and Formulas not marked and Numbers marked).

#### Example

=RANDBETWEEN(20;30) returns an integer of between 20 and 30.

## RANDBETWEEN.NV

Returns an non-volatile integer random number in a specified range.

#### Syntax

RANDBETWEEN.NV(Bottom; Top)

Returns an non-volatile integer random number between integers Bottom and Top (both inclusive). A non-volatile function is not recalculated at new input events or pressing F9. However, the function is recalculated when pressing F9 with the cursor on the cell containing the function, when opening the file, when using the Recalculate Hard command (Shift+CommandCtrl+F9) and when Top or Bottom are recalculated.

#### Example

=RANDBETWEEN.NV(20;30) returns a non-volatile integer between 20 and 30.

=RANDBETWEEN.NV(A1;30) returns a non-volatile integer between the value of cell A1 and 30. The function is recalculated when the contents of cell A1 change.

#### Technical information

This function is available since LibreOffice 7.0.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.LIBREOFFICE.RANDBETWEEN.NV

## RAND.NV

Returns a non-volatile random number between 0 and 1.

#### Syntax

RAND.NV()

This function produces a non-volatile random number on input. A non-volatile function is not recalculated at new input events. The function does not recalculate when pressing F9, except when the cursor is on the cell containing the function or using the Recalculate Hard command (Shift+CommandCtrl+F9). The function is recalculated when opening the file.

#### Example

=RAND.NV() returns a non-volatile random number between 0 and 1.

#### Technical information

This function is available since LibreOffice 7.0.

This function is NOT part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.LIBREOFFICE.RAND.NV

## ROUND

Rounds a number to a certain number of decimal places.

#### Syntax

ROUND(Number [; Count])

Returns Number rounded to Count decimal places. If Count is omitted or zero, the function rounds to the nearest integer. If Count is negative, the function rounds to the nearest 10, 100, 1000, etc.

This function rounds to the nearest number. See ROUNDDOWN and ROUNDUP for alternatives.

#### Example

=ROUND(2.348;2) returns 2.35

=ROUND(-32.4834;3) returns -32.483. Change the cell format to see all decimals.

=ROUND(2.348;0) returns 2.

=ROUND(2.5) returns 3.

=ROUND(987.65;-2) returns 1000.

## ROUNDDOWN

Truncates a number while keeping a specified number of decimal digits.

## ROUNDUP

Rounds a number up, away from zero, to a certain precision.

#### Syntax

ROUNDUP(Number [; Count])

Returns Number rounded up (away from zero) to Count decimal places. If Count is omitted or zero, the function rounds up to an integer. If Count is negative, the function rounds up to the next 10, 100, 1000, etc.

This function rounds away from zero. See ROUNDDOWN and ROUND for alternatives.

#### Example

=ROUNDUP(1.1111;2) returns 1.12.

=ROUNDUP(1.2345;1) returns 1.3.

=ROUNDUP(45.67;0) returns 46.

=ROUNDUP(-45.67) returns -46.

=ROUNDUP(987.65;-2) returns 1000.

## SEC

Returns the secant of the given angle (in radians). The secant of an angle is equivalent to 1 divided by the cosine of that angle

This function is available since LibreOffice 3.5.

#### Syntax

SEC(Number)

Returns the (trigonometric) secant of Number, the angle in radians.

To return the secant of an angle in degrees, use the RADIANS function.

#### Example

=SEC(PI()/4) returns approximately 1.4142135624, the inverse of the cosine of PI/4 radians.

=SEC(RADIANS(60)) returns 2, the secant of 60 degrees.

## SECH

Returns the hyperbolic secant of a number.

This function is available since LibreOffice 3.5.

#### Syntax

SECH(Number)

Returns the hyperbolic secant of Number.

#### Example

=SECH(0) returns 1, the hyperbolic secant of 0.

## SERIESSUM

Sums the first terms of a power series.

SERIESSUM(x;n;m;c) = c1xn + c2xn+m + c3xn+2m + ... + cixn + (i-1)m.

#### Syntax

SERIESSUM(X; N; M; Coefficients)

X is the input value for the power series.

N is the initial power

M is the increment to increase N

Coefficients is a series of coefficients. For each coefficient the series sum is extended by one section.

#### Example

=SERIESSUM(A1; 0; 1; {1; 2; 3}) calculates the value of 1+2x+3x2, where x is the value in cell A1. If A1 contains 1, the formula returns 6; if A1 contains 2, the formula returns 17; if A1 contains 3, the formula returns 34; and so on.

Refer to the SERIESSUM wiki page for more details about this function.

## SIGN

Returns the sign of a number. Returns 1 if the number is positive, -1 if negative and 0 if zero.

#### Syntax

SIGN(Number)

Number is the number whose sign is to be determined.

#### Example

=SIGN(3.4) returns 1.

=SIGN(-4.5) returns -1.

## SIN

Returns the sine of the given angle (in radians).

#### Syntax

SIN(Number)

Returns the (trigonometric) sine of Number, the angle in radians.

To return the sine of an angle in degrees, use the RADIANS function.

#### Example

=SIN(PI()/2) returns 1, the sine of PI/2 radians.

=SIN(RADIANS(30)) returns 0.5, the sine of 30 degrees.

## SINH

Returns the hyperbolic sine of a number.

#### Syntax

SINH(Number)

Returns the hyperbolic sine of Number.

#### Example

=SINH(0) returns 0, the hyperbolic sine of 0.

## SQRT

Returns the positive square root of a number.

#### Syntax

SQRT(Number)

Returns the positive square root of Number.

Number must be positive.

#### Example

=SQRT(16) returns 4.

=SQRT(-16) returns an invalid argument error.

## SQRTPI

Returns the square root of (PI times a number).

#### Syntax

SQRTPI(Number)

Returns the positive square root of (PI multiplied by Number).

This is equivalent to SQRT(PI()*Number).

#### Example

=SQRTPI(2) returns the squareroot of (2PI), approximately 2.506628.

## SUBTOTAL

Calculates subtotals. If a range already contains subtotals, these are not used for further calculations. Use this function with the AutoFilters to take only the filtered records into account.

#### Syntax

SUBTOTAL(Function; Range)

Function is a number that stands for one of the following functions:

Function index (includes hidden values) | Function index (ignores hidden values) | Function
--- | --- | ---
1 | 101 | AVERAGE
2 | 102 | COUNT
3 | 103 | COUNTA
4 | 104 | MAX
5 | 105 | MIN
6 | 106 | PRODUCT
7 | 107 | STDEV
8 | 108 | STDEVP
9 | 109 | SUM
10 | 110 | VAR
11 | 111 | VARP

Use numbers 1-11 to include manually hidden rows or 101-111 to exclude them; filtered-out cells are always excluded.

Range is the range whose cells are included.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

You have a table in the cell range A1:B6 containing a bill of material for 10 students.

| A | B
--- | --- | ---
1 | ITEM | QUANTITY
2 | Pen | 10
3 | Pencil | 10
4 | Notebook | 10
5 | Rubber | 10
6 | Sharpener | 10

Let's say one row is manually hidden, then the first formula shows the sum of the 5 figures filtered; the second, only the sum of the 4 figures displayed.

=SUBTOTAL(9;B2:B6) returns 50.

=SUBTOTAL(109;B2:B6) returns 40.

## SUMSQ

Calculates the sum of the squares of a set of numbers.

#### Syntax

SUMSQ(Number 1 [; Number 2 [; … [; Number 255]]])

Number 1; Number 2; … ; Number 255 are numbers, references to cells or to cell ranges of numbers.

This function ignores any text or empty cell within a data range. If you suspect wrong results from this function, look for text in the data ranges. To highlight text contents in a data range, use the value highlighting feature.

#### Example

If you enter the numbers 2; 3 and 4 in the Number 1; 2 and 3 arguments, 29 is returned as the result.

## TAN

Returns the tangent of the given angle (in radians).

#### Syntax

TAN(Number)

Returns the (trigonometric) tangent of Number, the angle in radians.

To return the tangent of an angle in degrees, use the RADIANS function.

#### Example

=TAN(PI()/4) returns 1, the tangent of PI/4 radians.

=TAN(RADIANS(45)) returns 1, the tangent of 45 degrees.

## TANH

Returns the hyperbolic tangent of a number.

#### Syntax

TANH(Number)

Returns the hyperbolic tangent of Number.

#### Example

=TANH(0) returns 0, the hyperbolic tangent of 0.

## TRUNC

Truncates a number while keeping a specified number of decimal digits.

Related Topics

Functions by Category